// ============================================================
// Chapter 0 · Block A0
// 命名约定：C{章节}_{BlockId}_{分段}
// 入口节点：C0_A0
// 分段节点：C0_A0_first_meeting / C0_A0_reveal / C0_A0_conceal
//           C0_A0_truth_known   / C0_A0_end
// ============================================================

title: C0_A0
position: 0,0
---
// 变量声明（默认值；StoryVariableStorage 存有存档值时会自动覆盖）
<<declare $asahi_knows_the_truth = false>>
<<declare $asahi_remembers_origin = false>>
SLS: 勇士，你终于来了。我们等待你很久了。 #line:0c2e7ae 
<<set_portrait "Asahi" 33 0>>
Asahi: ……这就是那个传说中的地方吗？ #line:0871a99 
<<jump C0_A0_first_meeting>>
===

title: C0_A0_first_meeting
position: -150,250
---
<<move_portrait "Asahi" -33 0 1.5>>
SLS: 这里曾是一场被时间掩埋的战争的终结之地。 #line:0cdce7d 
SLS: 我们称之为"遗忘之地"。 #line:0fe1e57 
<<jump_portrait "Asahi" 5 2 0.8>>
Asahi: 为什么叫这个名字？ #line:068875f 
SLS: 因为死去的人希望被遗忘—— #line:04a17d7 
<<shake_portrait "Asahi" 1.0 2 10>>
SLS: ——而活下来的人，却永远无法忘记。 #line:03e5d89 
Asahi: …… #line:0a4b2fc 

// 玩家选择：决定是否对朝日如实相告
-> 让朝日知道全部真相 #line:019f988 
    <<set $asahi_knows_the_truth = true>>
    <<jump C0_A0_reveal>>
-> 暂时不告诉朝日 #line:02b0524 
    <<jump C0_A0_conceal>>
-> 聊聊朝日的过去 <<if $asahi_remembers_origin>> #line:0e8d4c1 
    Asahi: 那段记忆……我终于能开口谈了。 #line:0a3f9b7 
    <<jump C0_A0_end>>
===

title: C0_A0_reveal
position: -250,500
---
SLS: 勇士，你选择了如实相告。这需要勇气。 #line:0f8c24f 
SLS: 朝日，你所在的这个世界，从未真正平静过。 #line:0b9f3b6 
SLS: 那场战争留下的烙印，至今仍深藏在每一片土地之下。 #line:0e67923 
Asahi: 我……我需要时间来接受这一切。 #line:0365430 
SLS: 我们等你。 #line:081f185 
<<set $asahi_remembers_origin = true>>
<<jump C0_A0_end>>
===

title: C0_A0_conceal
position: -50,500
---
SLS: 有些事，时机未到，不必强求。 #line:0a8fa30 
SLS: 今天先让朝日了解这里的历史就够了。 #line:09b7cff 
Asahi: 谢谢你。我会记住的。 #line:097c353 
<<jump C0_A0_end>>
===

title: C0_A0_truth_known
position: 150,250
---
SLS: 既然朝日已知晓实情，接下来的路会更加艰难。 #line:09fe68f 
SLS: 但你所拥有的力量，也会随觉悟的深入而增长。 #line:06154cb 
Asahi: 我已经准备好了。 #line:04617a4 
<<set $asahi_remembers_origin = true>>
<<jump C0_A0_end>>
===

title: C0_A0_end
position: 0,750
---
<<show_message "Test Title" "这是一条测试自定义信息的留言！">>
SLS: 无论你作何选择，这段旅途都只属于你。 #line:00bf206 
SLS: 去吧，勇士。前方还有很长的路。 #line:03c5112 
Asahi: 我会一直陪着你的，不管去哪里。 #line:06d2a12 
===